Works set in San Francisco
SELECT ?work ?workLabel WHERE {
?work wdt:P840 wd:Q62 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
National Register of Historic Places by US county and state
select ?county ?countyLabel ?stateLabel (count(*) as ?count) where {
?county wdt:P31/wdt:P279* ?county_of_state .
?county_of_state wdt:P279 wd:Q47168 .
?county_of_state wdt:P361* ?state .
?state wdt:P31 wd:Q35657 .
?item wdt:P649 ?nrhp .
?item wdt:P131 ?county .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} GROUP BY ?county ?countyLabel ?stateLabel
Mass shootings
SELECT ?item ?itemLabel ?isaLabel ?deaths ?date ?countryLabel
WHERE
{
?item wdt:P31/wdt:P279* wd:Q21480300 .
?item wdt:P31 ?isa
optional { ?item wdt:P1120 ?deaths } .
optional { ?item wdt:P585 ?date } .
optional { ?item wdt:P17 ?country } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
countries
Countries with ISO 3166 code and continent
SELECT ?iso3166 ?country ?countryLabel ?continentLabel WHERE {
OPTIONAL { ?country wdt:P297 ?iso3166 }
?country wdt:P31 wd:Q3624078 . # sovereign state
OPTIONAL { ?country wdt:P30 ?continent }
FILTER NOT EXISTS {?country wdt:P31 wd:Q3024240}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en"}
} ORDER BY ?iso3166 ?continentLabel ?countryLabel
Places with an ISO 3166 code tat aren't sovereign states.
SELECT ?iso3166 ?country ?countryLabel ?continentLabel WHERE {
?country wdt:P297 ?iso3166 .
FILTER NOT EXISTS {?country wdt:P31 wd:Q3624078}
OPTIONAL { ?country wdt:P30 ?continent }
FILTER NOT EXISTS {?country wdt:P31 wd:Q3024240}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en"}
} ORDER BY ?iso3166 ?continentLabel ?countryLabel
brewpubs and brewpub chains
SELECT ?item ?itemLabel ?type ?founded ?locationLabel ?countryLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
{ ?item wdt:P31 wd:Q3640372 .BIND ("brewpub" as ?type) }
UNION
{ ?item wdt:P31 wd:Q42360247 . BIND ("brewpub chain" as ?type) }
OPTIONAL { ?item wdt:P17 ?country }
OPTIONAL { ?item wdt:P571 ?founded }
OPTIONAL { ?item wdt:P131 ?location }
}
ORDER BY ?type ?item
Find country via HQ for breweries
SELECT ?item ?itemLabel ?hqCountry ?hqCountryLabel ?hqLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q131734.
filter not exists { ?item wdt:P17 ?country }
?item wdt:P159 ?hq .
?hq wdt:P17 ?hqCountry .
}
Things with a country that don't match the HQ country
SELECT ?item ?itemLabel ?country ?countryLabel ?hqCountryLabel ?hqLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P17 ?country .
?item wdt:P159 ?hq .
?hq wdt:P17 ?hqCountry .
FILTER ( ?hqCountry != ?country ) .
filter not exists { ?country wdt:P31 wd:Q3024240 } .
}
Musicians that killed themselves
SELECT DISTINCT ?item ?itemLabel ?dod ?death ?deathLabel ?countryLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P1196 wd:Q10737 .
?item wdt:P31 wd:Q5 .
OPTIONAL { ?item wdt:P570 ?dod . }
OPTIONAL { ?item wdt:P509 ?death . }
OPTIONAL { ?item wdt:P27 ?country . }
{
?item wdt:P106/wdt:P279* wd:Q639669 .
} UNION {
?item wdt:P106/wdt:P279* wd:Q177220 .
} UNION {
?item wdt:P106/wdt:P279* wd:Q753110 .
}
} ORDER BY DESC(?dod)
Recent deaths
SELECT DISTINCT ?item ?itemLabel ?dob ?dod ?placeLabel ?deathLabel
(GROUP_CONCAT(DISTINCT(?jobLabel); separator=", ") as ?jobs)
(GROUP_CONCAT(DISTINCT(?countryLabel); separator=", ") as ?country)
WHERE {
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?job rdfs:label ?jobLabel .
?country rdfs:label ?countryLabel .
?item rdfs:label ?itemLabel .
?place rdfs:label ?placeLabel .
}
?item wdt:P31 wd:Q5 . ?item wdt:P570 ?dod .
OPTIONAL { ?item wdt:P106 ?job . } OPTIONAL { ?item wdt:P20 ?place . } OPTIONAL { ?item wdt:P569 ?dob . }
OPTIONAL { ?item wdt:P1196 ?death . } OPTIONAL { ?item wdt:P27 ?country . }
FILTER (?dod >= "2017-11-00T00:00:00Z"^^xsd:dateTime) FILTER (?dod <= "2017-11-15T00:00:00Z"^^xsd:dateTime)
}
GROUP BY ?item ?itemLabel ?dob ?dod ?placeLabel ?deathLabel ORDER BY DESC(?dod)
Family names with a religion
SELECT ?family ?familyLabel ?religionLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?family wdt:P31 wd:Q101352 .
?family wdt:P140 ?religion .
}
Current UK members of parliament
SELECT ?item ?itemLabel ?dob ?countryLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P39 wd:Q30524710.
OPTIONAL { ?item wdt:P569 ?dob }
OPTIONAL { ?item wdt:P27 ?country }
}
Tech start-up founders
SELECT ?founder ?founderLabel ?company ?companyLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?company wdt:P31 wd:Q4830453 .
{
?company wdt:P452 wd:Q11661
} UNION {
?company wdt:P452 wd:Q21157865
} UNION {
?company wdt:P452 wd:Q880371
} UNION {
?company wdt:P452 wd:Q638608
} UNION {
?company wdt:P452 wd:Q75
}
?company wdt:P112 ?founder .
}
Cities
SELECT ?item ?itemLabel (sample(?pop) as ?pop) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q515 .
?item wdt:P1082 ?pop .
FILTER (?pop > 500000)
} group by ?item ?itemLabel
625 results.
Looking for missing "city with millions of inhabitants"
Looking for cities with more than 1 million people without being instance of "city with millions of inhabitants".
This isn't working correctly.
SELECT ?item ?itemLabel ?pop WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q515 .
?item wdt:P1082 ?pop .
FILTER NOT EXISTS {?item wdt:P31 wd:Q1637706 . }
FILTER (?pop > 1000000)
}
Books in English in the Welsh language Wikipedia that are missing English labels
SELECT ?item ?itemLabel WHERE {
?item wdt:P31 wd:Q571.
?item wdt:P407 wd:Q1860 .
?item rdfs:label ?itemLabel
FILTER(LANG(?itemLabel) = "cy")
FILTER(NOT EXISTS {
?item rdfs:label ?itemLabel2
FILTER(LANG(?itemLabel2) = "en")
})
}
Books in English in that are missing English labels
SELECT DISTINCT ?item ?itemLabel (LANG(?itemLabel) as ?lang) WHERE {
?item wdt:P31 wd:Q571.
?item wdt:P407 wd:Q1860 .
?item rdfs:label ?itemLabel
FILTER(NOT EXISTS {
?item rdfs:label ?itemLabel2
FILTER(LANG(?itemLabel2) = "en")
})
}
Humans that have a Welsh label, but not an English label
SELECT ?item ?itemLabel WHERE {
?item wdt:P31 wd:Q5.
?item rdfs:label ?itemLabel
FILTER(LANG(?itemLabel) = "cy")
FILTER(NOT EXISTS {
?item rdfs:label ?itemLabel2
FILTER(LANG(?itemLabel2) = "en")
})
}
UK people without an English label
SELECT ?item (GROUP_CONCAT(DISTINCT(?itemLabel); separator="|") as ?labels) WHERE {
?item wdt:P31 wd:Q5.
?item wdt:P27 wd:Q145 .
?item rdfs:label ?itemLabel
FILTER(LANG(?itemLabel) != "en")
FILTER(NOT EXISTS {
?item rdfs:label ?itemLabel2
FILTER(LANG(?itemLabel2) = "en")
})
} GROUP BY ?item
List of languages, writing systems and Wikimedia language code
SELECT ?item ?itemLabel ?writing ?writingLabel ?code WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q34770 .
?item wdt:P282 ?writing .
?item wdt:P424 ?code .
}
Find bad OSM Key or Tag
SELECT ?item ?itemLabel ?osm WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P1282 ?osm.
FILTER NOT EXISTS {
FILTER regex(?osm,'^Key:')
}
FILTER NOT EXISTS {
FILTER regex(?osm,'^Tag:')
}
}
Things with OSM Key or Tag but no English language label
SELECT ?item ?osm WHERE {
?item wdt:P1282 ?osm.
FILTER(NOT EXISTS {
?item rdfs:label ?itemLabel
FILTER(LANG(?itemLabel) = "en")
})
}
Parks with a Commons category, but no English language label
SELECT ?item (GROUP_CONCAT(DISTINCT(?itemLabel); separator="|") as ?labels) ?cat WHERE {
?item wdt:P373 ?cat .
?item wdt:P31 wd:Q22698 .
?item rdfs:label ?itemLabel .
FILTER(LANG(?itemLabel) != "en")
FILTER(NOT EXISTS {
?item rdfs:label ?itemLabel2
FILTER(LANG(?itemLabel2) = "en")
})
} GROUP BY ?item ?cat
People with country of citizenship set to China (region)
SELECT ?item ?itemLabel ?dob WHERE {
?item wdt:P27 wd:Q29520 .
OPTIONAL { ?item wdt:P569 ?dob }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
2,986 Results
Churches in Norway
SELECT ?item ?itemLabel ?coords WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q16970 .
?item wdt:P17 wd:Q20 .
OPTIONAL { ?item wdt:P625 ?coords }
}
Admin subdivisions of Cambridgeshire (county council area)
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
VALUES ?start { wd:Q21272276 } .
?start wdt:P150 ?item .
}
Ceremonial counties in East of England
SELECT DISTINCT ?item ?itemLabel ?startLabel WHERE {
VALUES ?start { wd:Q48006 } .
?item wdt:P31 wd:Q180673 .
?item wdt:P131 ?start .
?item wdt:P31 ?isa .
FILTER NOT EXISTS { ?item wdt:P31 wd:Q9046617 } .
FILTER NOT EXISTS { ?item wdt:P31/wdt:P279* wd:Q19953632 } .
FILTER NOT EXISTS { ?item wdt:P31/wdt:P279* wd:Q15893266 } .
FILTER NOT EXISTS { ?item wdt:P576 ?end } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY ?itemLabel
Districts of India in Telangana
SELECT DISTINCT ?item ?itemLabel WHERE {
?item wdt:P131 wd:Q677037 .
?item wdt:P31 wd:Q1149652 .
FILTER NOT EXISTS { ?item wdt:P576 ?end } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY ?itemLabel
Continents and country counts
Ignore continents with only one country
SELECT ?continent ?continentLabel ?count WHERE {
{
SELECT ?continent ?continentLabel (COUNT(?country) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?country wdt:P30 ?continent .
?country wdt:P31 wd:Q6256 .
}
GROUP BY ?continent ?continentLabel
ORDER BY ?continentLabel
}
FILTER (?count > 1)
}
Pubs in the UK tagged as inns.
List of pubs with the word 'inn' in the name. Incorrectly tagged as pubs. 2,857 results.
SELECT ?item ?itemLabel WHERE
{
?item wdt:P31 wd:Q256020 .
?item wdt:P17 wd:Q145 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Languages with an IETF language tag
SELECT ?item ?itemLabel ?code {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P305 ?code .
} ORDER BY ?code
MPs elected since 2005
SELECT ?item ?itemLabel ?dob WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P39 ?parliament .
?parliament wdt:P279 wd:Q16707842 .
?parliament wdt:P571 ?start .
?item wdt:P569 ?dob .
FILTER (?start > "2005-01-00T00:00:00Z"^^xsd:dateTime)
} ORDER BY DESC (?dob)
department of Argentina without a label in English
27 results
SELECT ?item ?itemLabel WHERE {
?item wdt:P31 wd:Q952274.
?item rdfs:label ?itemLabel
FILTER(LANG(?itemLabel) = "es")
FILTER(NOT EXISTS {
?item rdfs:label ?itemLabel2
FILTER(LANG(?itemLabel2) = "en")
})
}
administrative territorial entity of Argentina without an English label
SELECT ?item ?itemLabel ?countryLabel WHERE {
?item wdt:P31/wdt:P279* wd:Q3042547 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],es" }
OPTIONAL { ?item wdt:P17 ?country . }
FILTER(NOT EXISTS {
?item rdfs:label ?itemLabel2
FILTER(LANG(?itemLabel2) = "en")
})
}
people with citizenship set to language by mistake
select ?person ?personLabel ?item ?itemLabel where {
?item wdt:P31 wd:Q34770 .
?person wdt:P27 ?item .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
141 results
people with place of death as a year item
select ?person ?personLabel ?item ?itemLabel where {
?item wdt:P31 wd:Q577 .
?person wdt:P20 ?item .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
19 results
Instance of 'consulate', should be 'consulate general'
select ?item ?itemLabel where {
?item wdt:P31 wd:Q7843791 .
?item rdfs:label ?label .
FILTER regex(?label, 'eneral')
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
districts of the United Kingdom in Oxfordshire
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q17601336 .
?item wdt:P131 wd:Q23169 .
}
books written by journalists
15,189 results
select ?person ?personLabel ?book ?bookLabel ?date where {
?person wdt:P106 wd:Q1930187 .
?book wdt:P31 wd:Q571 .
?book wdt:P50 ?person .
?book wdt:P577 ?date .
service wikibase:label { bd:serviceParam wikibase:language "en" }
} order by desc(?date)
books written by health professionals
select distinct ?person ?personLabel ?book ?bookLabel ?date where {
?person wdt:P106/wdt:P279* wd:Q11974939 .
?book wdt:P31 wd:Q571 .
?book wdt:P50 ?person .
?book wdt:P577 ?date .
service wikibase:label { bd:serviceParam wikibase:language "en" }
} order by desc(?date)
administrative territorial entity of a single country
exclude historical countries
215 results.
select ?item ?itemLabel ?country ?countryLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P279 wd:Q15916867 .
?item wdt:P17 ?country .
filter not exists {
?country wdt:P31 wd:Q3024240 .
}
}
Tall buidings
SELECT ?item ?itemLabel ?height WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q811979 .
?item p:P2048/psn:P2048/wikibase:quantityAmount ?height .
filter (?height > 200)
}
Streets named after people
select distinct ?item ?itemLabel ?country ?countryLabel ?namedAfter ?namedAfterLabel ?job ?jobLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31 wd:Q79007 .
optional {?item wdt:P17 ?country}
?item wdt:P138 ?namedAfter .
?namedAfter wdt:P31 wd:Q5 .
optional {?namedAfter wdt:P106 ?job }
} limit 100
things named after physicist
751 results
select distinct ?item ?itemLabel ?isa ?isaLabel ?itemCountry ?itemCountryLabel ?person ?personLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31 ?isa .
?item wdt:P17 ?itemCountry .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106/wdt:P279* wd:Q169470 .
filter (?isa != wd:Q79007)
}
Airports named after people by job
202 results
select distinct ?job ?jobLabel (count(*) as ?count) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106/wdt:P279* ?job .
?job wdt:P31/wdt:P279* wd:Q28640 .
} GROUP BY ?job ?jobLabel ORDER BY DESC(?count)
Airports named after poets
select distinct ?item ?itemLabel ?itemCountry ?itemCountryLabel ?person ?personLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 ?itemCountry .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q49757 .
}
Airports named after poets with date of birth and death
select distinct ?item ?itemLabel ?itemCountry ?itemCountryLabel ?person ?personLabel ?birth ?death where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 ?itemCountry .
?item p:P138 ?statement .
?statement ps:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q49757 .
optional { ?person wdt:P569 ?birth }
optional { ?person wdt:P570 ?death }
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
}
Airports named after poets with more detail
SELECT DISTINCT ?airport ?airportLabel (sample(?coords) as ?coords) ?airportCountry ?airportCountryLabel ?person ?personLabel ?personImage (sample(?birth) as ?birth) (SAMPLE(?death) as ?death) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
?airport (wdt:P31/(wdt:P279*)) wd:Q1248784;
wdt:P17 ?airportCountry;
p:P138 ?statement.
?statement ps:P138 ?person.
?person wdt:P31 wd:Q5;
wdt:P106 wd:Q49757.
optional { ?person wdt:P18 ?personImage }
OPTIONAL { ?airport wdt:P625 ?coords }
OPTIONAL { ?person wdt:P569 ?birth }
OPTIONAL { ?person wdt:P570 ?death }
FILTER(NOT EXISTS { ?statement pq:P582 ?endTime. })
} group by ?airport ?airportLabel ?airportCountry ?airportCountryLabel ?person ?personLabel ?personImage
How many airports are named after a person in each country
91 countries
select ?itemCountry ?itemCountryLabel (count(*) as ?count) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 ?itemCountry .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
} group by ?itemCountry ?itemCountryLabel order by DESC(?count)
Airports named after poets with date of birth and death
select distinct ?item ?itemLabel ?itemCountry ?itemCountryLabel ?place ?placeLabel ?person ?personLabel (year(?dob) as ?born) (year(?dod) as ?died) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 ?itemCountry .
?item p:P138 ?statement .
?statement ps:P138/wdt:P138* ?person .
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q49757 .
optional { ?item wdt:P931 ?place }
optional { ?person wdt:P569 ?dob }
optional { ?person wdt:P570 ?dod }
}
Type of things stations are named after
select distinct ?isa ?isaLabel (sample(?item) as ?sample) (count(*) as ?count) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q55488 .
?item p:P138 ?statement .
?statement ps:P138/wdt:P138* ?person .
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
?person wdt:P31 ?isa .
filter (?isa != wd:Q5 )
filter not exists { ?person wdt:P31/wdt:P279* wd:Q486972 }
filter not exists { ?person wdt:P31/wdt:P279* wd:Q56061 }
} group by ?isa ?isaLabel order by desc(?count)
Bridges named after poets
41 results
select distinct ?item ?itemLabel ?itemCountry ?itemCountryLabel ?place ?placeLabel ?person ?personLabel (year(?dob) as ?born) (year(?dod) as ?died) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q12280 .
?item wdt:P17 ?itemCountry .
?item p:P138 ?statement .
?statement ps:P138/wdt:P138* ?person .
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
?person wdt:P106 wd:Q49757 .
optional { ?item wdt:P131 ?place }
optional { ?person wdt:P569 ?dob }
optional { ?person wdt:P570 ?dod }
}
Things named after themselves
select distinct ?item ?itemLabel ?itemCountry ?itemCountryLabel ?isa ?isaLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P138 ?item .
optional { ?item wdt:P31 ?isa }
optional { ?item wdt:P17 ?itemCountry }
}
Island airports
select distinct ?item ?itemLabel ?itemCountry ?itemCountryLabel ?place ?placeLabel ?island ?islandLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 ?itemCountry .
?item wdt:P931 ?place .
?place wdt:P31 wd:Q23442 .
optional { ?item wdt:P5130 ?island }
}
Islands named after poets
3 results
select distinct ?item ?itemLabel ?itemCountry ?itemCountryLabel ?place ?placeLabel ?person ?personLabel (year(?dob) as ?born) (year(?dod) as ?died) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q23442 .
?item wdt:P17 ?itemCountry .
?item p:P138 ?statement .
?statement ps:P138/wdt:P138* ?person .
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q49757 .
optional { ?item wdt:P131 ?place }
optional { ?person wdt:P569 ?dob }
optional { ?person wdt:P570 ?dod }
}
Things (other than streets) named after people
select distinct ?item ?itemLabel ?isa ?isaLabel ?itemCountry ?itemCountryLabel ?person ?personLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31 ?isa .
?item wdt:P17 ?itemCountry .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106/wdt:P279* wd:Q169470 .
filter (?isa != wd:Q79007)
}
Airports named after boxers
select distinct ?item ?itemLabel ?itemCountry ?itemCountryLabel ?person ?personLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 ?itemCountry .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q11338576 .
}
Railway stations named after jobs
155 results
select distinct ?job ?jobLabel (count(*) as ?count) (sample(?item) as ?sample) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q55488 .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 ?job .
} GROUP BY ?job ?jobLabel ORDER BY DESC(?count)
Airports named after possibly living people
32 results
Need to add a special case to handle married couple for Clinton National Airport
select distinct ?item ?itemLabel ?itemCountry ?itemCountryLabel ?person ?personLabel ?birth where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 ?itemCountry .
?item p:P138 ?statement .
?statement ps:P138 ?person .
?person wdt:P31 wd:Q5 .
optional { ?person wdt:P569 ?birth }
FILTER NOT EXISTS { ?person wdt:P570 ?death }
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
}
Airports named after librarians
select ?item ?itemLabel ?person ?personLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P138+ ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106/wdt:P279* wd:Q182436 .
}
Airports named after poets, with photos and coordinates
select distinct ?item ?itemLabel ?image ?coordinates ?itemCountry ?itemCountryLabel ?place ?placeLabel ?person ?personLabel (year(?dob) as ?born) (year(?dod) as ?died) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 ?itemCountry .
?item p:P138 ?statement .
optional { ?item wdt:P625 ?coordinates }
optional { ?item wdt:P18 ?image }
?statement ps:P138/wdt:P138* ?person .
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q49757 .
optional { ?item wdt:P931 ?place }
optional { ?person wdt:P569 ?dob }
optional { ?person wdt:P570 ?dod }
}
Railway stations named after literary works
select distinct ?item ?itemLabel ?image ?coordinates ?itemCountry ?itemCountryLabel ?place ?placeLabel ?person ?personLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q55488 .
?item wdt:P17 ?itemCountry .
?item p:P138 ?statement .
optional { ?item wdt:P625 ?coordinates }
optional { ?item wdt:P18 ?image }
?statement ps:P138/wdt:P138* ?person .
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
?person wdt:P31/wdt:P279* wd:Q7725634 .
optional { ?item wdt:P931 ?place }
}
What type of things are stations named after, excluding people
select distinct ?isa ?isaLabel (sample(?item) as ?sample) (count(*) as ?count) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q55488 .
?item p:P138 ?statement .
?statement ps:P138/wdt:P138* ?person .
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
?person wdt:P31 ?isa .
filter (?isa != wd:Q5 )
filter not exists { ?person wdt:P31/wdt:P279* wd:Q486972 }
filter not exists { ?person wdt:P31/wdt:P279* wd:Q56061 }
} group by ?isa ?isaLabel order by desc(?count)
Books by surgeons
select distinct ?person ?personLabel ?book ?bookLabel ?date where {
?person wdt:P106/wdt:P279* wd:Q774306 .
?book wdt:P31 wd:Q571 .
?book wdt:P50 ?person .
?book wdt:P577 ?date .
service wikibase:label { bd:serviceParam wikibase:language "en" }
} order by desc(?date)
Married couples
486 results. I few without labels in English
select ?item ?itemLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q3046146 .
}
Asteroids named after poets
select distinct ?item ?itemLabel ?person ?personLabel (year(?dob) as ?born) (year(?dod) as ?died) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q3863 .
?item p:P138 ?statement .
?statement ps:P138/wdt:P138* ?person .
FILTER NOT EXISTS { ?statement pq:P582 ?endTime }
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q49757 .
optional { ?person wdt:P569 ?dob }
optional { ?person wdt:P570 ?dod }
}
Things named after poets
select distinct ?isa ?isaLabel (count(*) as ?count) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31 ?isa .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q49757 .
} group by ?isa ?isaLabel order by desc(?count)
Jobs of people with impact craters named after them
select distinct ?job ?jobLabel (count(*) as ?count) (sample(?item) as ?sample) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q55818 .
?item wdt:P138+ ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 ?job .
} GROUP BY ?job ?jobLabel ORDER BY DESC(?count)
Things named after writers
select distinct ?isa ?isaLabel (count(*) as ?count) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31 ?isa .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q36180 .
} group by ?isa ?isaLabel order by desc(?count)
what types of things are named after french anarchists?
select distinct ?isa ?isaLabel (count(*) as ?count) (sample(?item) as ?sample) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31 ?isa .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q12961474 .
?person wdt:P27 wd:Q142 .
} group by ?isa ?isaLabel order by desc(?count)
select distinct ?item ?itemLabel ?isa ?isaLabel ?person ?personLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P138 ?person .
?item wdt:P31 ?isa .
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q12961474 .
?person wdt:P27 wd:Q142 .
}
Count of paintings with an image
result: 94,291
select (count(*) as ?count) where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
?painting wdt:P31 wd:Q3305213 .
?painting wdt:P18 ?image .
}
Jobs of people with peninsulas named after them
select distinct ?job ?jobLabel (count(*) as ?count) (sample(?item) as ?sample) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q34763 .
?item wdt:P138+ ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 ?job .
} GROUP BY ?job ?jobLabel ORDER BY DESC(?count)
Type of things named after statisticians
select distinct ?isa ?isaLabel (count(*) as ?count) (sample(?item) as ?sample) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31 ?isa .
?item wdt:P138 ?person .
?person wdt:P106 wd:Q2732142 .
} group by ?isa ?isaLabel order by desc(?count)
Paintings with value of P180 depicts statement
select ?painting ?paintingLabel ?article ?depicts ?depictsLabel where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
?painting wdt:P31 wd:Q3305213 .
?article schema:about ?painting .
?article schema:isPartOf <https://en.wikipedia.org/>.
?painting wdt:P180 ?depicts
} LIMIT 100
Simple version of airports named after poets
select ?airport ?poet where {
?airport wdt:P31/wdt:P279* wd:Q1248784 .
?airport wdt:P138 ?poet .
?poet wdt:P106 wd:Q49757 .
}
Paintings with an enwiki sitelink but no depicts (P180) statement
select ?painting ?paintingLabel ?image ?article where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
?painting wdt:P31 wd:Q3305213 .
?painting wdt:P18 ?image .
?article schema:about ?painting .
?article schema:isPartOf <https://en.wikipedia.org/>.
FILTER NOT EXISTS { ?painting wdt:P180 ?depicts }
}
painting depicts (P180) counts
causes timeout
select ?depicts ?depictsLabel (count(*) as ?count) where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
?painting wdt:P31 wd:Q3305213 .
?painting wdt:P180 ?depicts
} group by ?depicts ?depictsLabel order by desc(?count)
painting with image, missing depicts (P180) and no enwiki or commons category
59653 results
select ?painting ?paintingLabel where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
?painting wdt:P31 wd:Q3305213 .
?painting wdt:P18 ?image .
FILTER NOT EXISTS { ?painting wdt:P373 ?commons }
FILTER NOT EXISTS { ?painting wdt:P180 ?depicts }
FILTER NOT EXISTS {
?article schema:about ?painting .
?article schema:isPartOf <https://en.wikipedia.org/>.
}
} limit 100
entities with both ISO 3166-1 alpha 2 and alpha 3 code.
SELECT ?item ?itemLabel ?iso_alpha_2 ?iso_alpha_3 WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P297 ?iso_alpha_2 .
?item wdt:P298 ?iso_alpha_3 .
}
labels in all languages for country-like entities
SELECT ?item
?alpha2
?alpha3
(GROUP_CONCAT(DISTINCT(?label); separator = "|") AS ?label_list)
WHERE {
OPTIONAL { ?item wdt:P297 ?alpha2 }
OPTIONAL { ?item wdt:P298 ?alpha3 }
?item rdfs:label ?label .
FILTER NOT EXISTS { ?item wdt:P31 wd:Q3024240 }
} GROUP BY ?item ?alpha2 ?alpha3
english label, aliases, demonyms for country-like entities
SELECT ?item
?itemLabel
?alpha2
?alpha3
(GROUP_CONCAT(DISTINCT(?altLabel); separator = "|") AS ?altLabel_list)
(GROUP_CONCAT(DISTINCT(?demonym); separator = "|") AS ?demonym_list)
WHERE {
{
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
OPTIONAL { ?item wdt:P297 ?alpha2 }
OPTIONAL { ?item wdt:P298 ?alpha3 }
} UNION {
VALUES ?item { wd:Q458 wd:Q1065 }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
FILTER NOT EXISTS { ?item wdt:P31 wd:Q3024240 }
OPTIONAL { ?item skos:altLabel ?altLabel }
OPTIONAL { ?item wdt:P1549 ?demonym }
} GROUP BY ?item ?itemLabel ?alpha2 ?alpha3
Countries and codes
SELECT ?item ?itemLabel ?alpha2 ?alpha3 (GROUP_CONCAT(DISTINCT(?altLabel); separator = "|") AS ?altLabel_list) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
OPTIONAL { ?item wdt:P297 ?alpha2 }
OPTIONAL { ?item wdt:P298 ?alpha3 }
FILTER NOT EXISTS { ?item wdt:P31 wd:Q3024240 }
OPTIONAL {
?item skos:altLabel ?altLabel .
FILTER (lang(?altLabel) = "en")
FILTER (strlen(?altLabel) > 4)
}
} GROUP BY ?item ?itemLabel ?alpha2 ?alpha3
SELECT ?item ?itemLabel ?alpha2 ?alpha3 (GROUP_CONCAT(DISTINCT(?altLabel); separator = "|") AS ?altLabel_list) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
OPTIONAL { ?item wdt:P297 ?alpha2 }
OPTIONAL { ?item wdt:P298 ?alpha3 }
FILTER NOT EXISTS { ?item wdt:P31 wd:Q3024240 }
OPTIONAL { ?item skos:altLabel ?altLabel }
} GROUP BY ?item ?itemLabel ?alpha2 ?alpha3
limit 10
UK council websites
SELECT DISTINCT ?item ?itemLabel ?countryLabel ?url WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES (?isa) { (wd:Q1187580) (wd:Q1006876) (wd:Q3957)} .
?item wdt:P31 ?isa .
?item wdt:P17 wd:Q145 .
?item wdt:P856 ?url .
FILTER NOT EXISTS { ?item wdt:P31 wd:Q19953632 }
}
UK town websites
565 results
SELECT DISTINCT ?item ?itemLabel ?url WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q3957 .
?item wdt:P17 wd:Q145 .
?item wdt:P856 ?url .
}
Pubs in Westminster
78 results
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q212198 .
?item wdt:P131 wd:Q179351 .
}
OSM tags that start with Tag:shop
164 results
SELECT ?item ?itemLabel ?osm WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P1282 ?osm .
FILTER ( STRSTARTS(?osm, "Tag:shop") )
}
Photos of cafés
190 results
SELECT ?item ?itemLabel ?img WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q30022 .
?item wdt:P18 ?img .
}
Pubs in Westminster called the Red Lion
#defaultView:Map
SELECT ?item ?itemLabel ?coords WHERE {
?item rdfs:label ?itemLabel.
?item wdt:P31 wd:Q212198 .
?item wdt:P131 wd:Q179351 .
?item wdt:P625 ?coords .
FILTER(?itemLabel = "Red Lion"@en)
}
Things with the same photo
PREFIX geof: <http://www.opengis.net/def/geosparql/function/>
SELECT DISTINCT ?item1 ?item1Label ?isa1 ?isa1Label ?item2 ?item2Label ?isa2 ?isa2Label WHERE {
?item1 wdt:P18 ?img.
?item2 wdt:P18 ?img.
?item1 wdt:P625 ?coords1.
?item2 wdt:P625 ?coords2.
?item1 wdt:P17 wd:Q145 .
?item1 wdt:P31 ?isa1 .
?item2 wdt:P31 ?isa2 .
BIND(geof:distance(?coords1, ?coords2) AS ?dist)
FILTER(?dist < 2 && ?item1 != ?item2 && ?isa1 = ?isa2 && ?isa1 != wd:Q18536594 && ?isa1 != wd:Q55488)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} limit 300
Ruins in the UK
select ?item ?itemLabel ?nhle {
?item wdt:P17 wd:Q145 .
?item wdt:P1216 ?nhle .
?item rdfs:label ?itemLabel .
FILTER ( STRSTARTS(?itemLabel, "Remains of") )
}
Church ruins
56 results. These should be changed to: church ruin (Q17485079)
select ?item ?itemLabel ?country ?countryLabel {
?item wdt:P31 wd:Q109607 .
?item wdt:P31 wd:Q16970 .
OPTIONAL {
?item wdt:P17 ?country
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
castle ruins
167 results. These should be changed to: castle ruin (Q17715832)
SELECT ?item ?itemLabel ?country ?countryLabel WHERE {
?item wdt:P31 wd:Q109607.
?item wdt:P31 wd:Q23413.
OPTIONAL { ?item wdt:P17 ?country. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
district of England with parent to child relationship missing
select ?item ?itemLabel ?parent ?parentLabel {
?item wdt:P31/wdt:P279* wd:Q349084 .
?item wdt:P131 ?parent .
FILTER NOT EXISTS { ?parent wdt:P150 ?item }
FILTER NOT EXISTS { ?item wdt:P31 wd:Q9046617 }
FILTER NOT EXISTS { ?item wdt:P31 wd:Q19953632 }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Find things that should be instance of a subclass
Fails with a timeout
SELECT ?item ?itemLabel ?class ?classLabel ?subclass1Label ?subclass2Label WHERE {
?item wdt:P31 ?subclass1 .
?item wdt:P31 ?subclass2 .
?subclass1 wdt:P279* wd:Q35145743 .
?subclass2 wdt:P279* wd:Q35145743 .
?item wdt:P17 wd:Q145 .
?class wdt:P279 ?subclass1 .
?class wdt:P279 ?subclass2 .
?class wdt:P31/wdt:P279* wd:Q35145743 .
FILTER (?subclass1 != ?subclass2)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} LIMIT 100
states with limited recognition
SELECT ?country ?countryLabel ?iso WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?country p:P31 ?statement .
?statement ps:P31 wd:Q15634554 .
FILTER NOT EXISTS { ?statement pq:P582 ?end }
FILTER NOT EXISTS { ?country wdt:P31/wdt:P279* wd:Q3024240 }
OPTIONAL { ?country wdt:P297 ?iso }
}
Footballers
SELECT ?player ?playerLabel ?dob ?dod ?team ?teamLabel ?start ?end WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
OPTIONAL { ?teamStatement pq:P580 ?start }
OPTIONAL { ?teamStatement pq:P582 ?end }
{
SELECT ?player ?dob ?dod (SAMPLE(?team) AS ?team) (SAMPLE(?teamStatement) AS ?teamStatement) WHERE {
?player wdt:P21 wd:Q6581097.
?player wdt:P31 wd:Q5.
?player p:P54 ?teamStatement .
?teamStatement ps:P54 ?team .
?player wdt:P106 wd:Q937857.
?team wdt:P17 wd:Q145.
?team wdt:P31 wd:Q476028.
?team wdt:P118 wd:Q9448.
OPTIONAL { ?player wdt:P569 ?dob. }
OPTIONAL { ?player wdt:P570 ?dod. }
}
GROUP BY ?player ?dob ?dod
HAVING ((COUNT(?team)) = 1)
}
}
Items in Stroud
#defaultView:Map
SELECT ?item ?itemLabel ?coords ?image WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
SERVICE wikibase:around {
?item wdt:P625 ?coords.
bd:serviceParam wikibase:center "Point(-2.21 51.74)"^^geo:wktLiteral .
bd:serviceParam wikibase:radius "1" .
}
OPTIONAL { ?item wdt:image ?image. }
?item wdt:P131 ?stroud.
}
Places called Glasgow, using Mediawiki search API
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?parent ?parentLabel ?num WHERE {
SERVICE wikibase:mwapi {
bd:serviceParam wikibase:api "EntitySearch" .
bd:serviceParam wikibase:endpoint "www.wikidata.org" .
bd:serviceParam mwapi:search "glasgow" .
bd:serviceParam mwapi:language "en" .
?item wikibase:apiOutputItem mwapi:item .
?num wikibase:apiOrdinal true .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q2221906 .
FILTER NOT EXISTS { ?item wdt:P31/wdt:P279* wd:Q192611 }
OPTIONAL {
?item p:P131 ?statement .
?statement ps:P131 ?parent .
FILTER NOT EXISTS { ?statement pq:P582 ?x }
}
} ORDER BY ASC(?num) LIMIT 50
brewery buildings with coordinates, not in the Czech Republic
SELECT ?item ?itemLabel ?coords ?country ?countryLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q57778855 .
?item wdt:P625 ?coords .
FILTER NOT EXISTS { ?item wdt:P17 wd:Q213 }
OPTIONAL { ?item wdt:P17 ?country }
}
restaurants with steakhouse in the name
SELECT ?item ?itemLabel WHERE {
?item wdt:P31 wd:Q11707 .
?item rdfs:label ?itemLabel.
FILTER(CONTAINS(LCASE(?itemLabel), "steakhouse"@en)).
}
tram stops
1,896 results
SELECT ?item ?itemLabel ?coords ?loc ?locLabel ?owner ?ownerLabel ?countryLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q2175765.
OPTIONAL { ?item wdt:P625 ?coords. }
OPTIONAL { ?item wdt:P131 ?loc. }
OPTIONAL { ?item wdt:P17 ?country. }
OPTIONAL { ?item wdt:P18 ?image. }
OPTIONAL { ?item wdt:P127 ?owner. }
} ORDER BY ?country
tram stops in San Francisco
101 results
SELECT ?place ?placeLabel ?coord ?loc ?locLabel
WHERE
{
wd:Q62 wdt:P625 ?sfLoc .
SERVICE wikibase:around {
?place wdt:P625 ?coord .
bd:serviceParam wikibase:center ?sfLoc .
bd:serviceParam wikibase:radius "50" .
} .
FILTER EXISTS { ?place wdt:P31 wd:Q2175765 } .
OPTIONAL { ?place wdt:P131 ?loc }
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
}
}
UK railway stations without a photo
SELECT DISTINCT ?item ?itemLabel ?code WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q55488 .
?item wdt:P4755 ?code.
FILTER NOT EXISTS { ?item wdt:P18 ?image }
}
Thinks with a UK railway station code
SELECT ?code ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P4755 ?code .
} ORDER BY ?code
UK railway station without a 'named after' statement
953 results
SELECT DISTINCT ?item ?itemLabel ?code WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q55488 .
?item wdt:P4755 ?code.
FILTER NOT EXISTS { ?item wdt:P138 ?name }
} order by strlen(str(?itemLabel))
Items that represent authors of a book
27,063 results
SELECT distinct ?author ?authorLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?book wdt:P31/wdt:P279* wd:Q571.
?book wdt:P50 ?author.
}
Publishers excluding record labels
SELECT DISTINCT ?item ?itemLabel ?country ?countryLabel ?location ?locationLabel ?hq ?hqLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q2085381 .
FILTER NOT EXISTS { ?item wdt:P31 wd:Q18127 }
OPTIONAL { ?item wdt:P17 ?country }
OPTIONAL { ?item wdt:P276 ?location }
OPTIONAL { ?item wdt:P159 ?hq }
}
Airports in a given country
select ?item ?itemLabel (max(?passengers) AS ?passengers) ?website ?isin ?isinLabel ?iata ?icao {
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 wd:Q145 .
?item wdt:P3872 ?passengers .
optional { ?item wdt:P131 ?isin }
optional { ?item wdt:P856 ?website }
optional { ?item wdt:P238 ?iata }
optional { ?item wdt:P239 ?icao }
FILTER NOT EXISTS { ?item wdt:P576 ?end }
FILTER NOT EXISTS { ?item wdt:P3999 ?close }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?item ?itemLabel ?website ?isin ?isinLabel ?iata ?icao
ORDER BY desc(?passengers)
Airports in a given country
select ?item ?itemLabel (max(?passengers) AS ?passengers) ?website ?country ?countryLabel ?iata ?icao {
?item wdt:P31/wdt:P279* wd:Q1248784 .
?item wdt:P17 ?country .
?item wdt:P3872 ?passengers .
optional { ?item wdt:P856 ?website }
optional { ?item wdt:P238 ?iata }
optional { ?item wdt:P239 ?icao }
FILTER NOT EXISTS { ?item wdt:P576 ?end }
FILTER NOT EXISTS { ?item wdt:P3999 ?close }
FILTER ( ?country != wd:Q148 )
FILTER ( ?passengers > 1000000 )
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?item ?itemLabel ?website ?country ?countryLabel ?iata ?icao
ORDER BY desc(?passengers)
Airports in a given country
select ?item ?itemLabel ?passengers ?website ?iata ?icao {
?item wdt:P31/wdt:P279* wd:Q1248784; p:P3872 [pq:P585 ?date; ps:P3872 ?passengers]
FILTER NOT EXISTS {?item p:P3872 [pq:P585 ?date_] FILTER (?date_ > ?date)}
?item wdt:P17 wd:Q145 .
optional { ?item wdt:P856 ?website }
optional { ?item wdt:P238 ?iata }
optional { ?item wdt:P239 ?icao }
FILTER NOT EXISTS { ?item wdt:P576 ?end }
FILTER NOT EXISTS { ?item wdt:P3999 ?close }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY desc(?passengers)
Cities in Los Angles County
select ?item ?itemLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P131 wd:Q104994 .
?item wdt:P31 wd:Q1093829 .
}
Country house hotel
select ?item ?itemLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q27686 .
?item wdt:P31/wdt:P279* wd:Q16884952 .
}
Libraries in Netherlands
SELECT ?item ?itemLabel ?isa ?isaLabel ?coords {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q7075 .
?item wdt:P31 ?isa .
?item wdt:P17 wd:Q55 .
?item wdt:P625 ?coords .
}
continent banners
SELECT ?continent ?continentLabel ?banner (COUNT(?country) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?country wdt:P30 ?continent .
?country wdt:P31 wd:Q6256 .
?continent wdt:P948 ?banner
}
GROUP BY ?continent ?continentLabel ?banner
ORDER BY ?continentLabel
count of items that are are visual artwork
select (count(*) as ?count) where {
?item wdt:P31/wdt:P279* wd:Q4502142 .
?item wdt:P18 ?image .
}
count of items that are are visual artwork, with some exclusions
select (count(*) as ?count) where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?subclass wdt:P279 wd:Q4502142 .
filter (?subclass != wd:Q11424) . # film
filter (?subclass != wd:Q112110) . # emblem
filter (?subclass != wd:Q4989906) . # monument
filter (?subclass != wd:Q20742776) . # video artwork
filter (?subclass != wd:Q1139104) . # computer wallpaper
filter (?subclass != wd:Q2995749) . # royal doors
filter (?subclass != wd:Q5567091) . # glass art
filter (?subclass != wd:Q2003285) . # Hedwig glass
filter (?subclass != wd:Q63957358) . # paperwork
filter (?subclass != wd:Q170984) . # crown
filter (?subclass != wd:Q1131329) . # grotto
filter (?subclass != wd:Q483453) . # fountain
filter (?subclass != wd:Q48498) . # illuminated manuscript
filter (?subclass != wd:Q64093742) . # Morris & Co. pattern
?item wdt:P31/wdt:P279* ?subclass .
?item wdt:P18 ?image .
}
UK towns, cities and villages with population
select distinct ?item ?itemLabel ?population ?coords ?isin ?isinLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES ?type { wd:Q3957 wd:Q515 wd:Q1549591 wd:Q200250 wd:Q2755753 wd:Q1357964 wd:Q18511725 wd:Q188509 wd:Q532 wd:Q6888356 wd:Q5119 }
?item wdt:P31 ?type .
?item wdt:P17 wd:Q145 .
optional { ?item wdt:P1082 ?population . }
?item wdt:P625 ?coords .
optional { ?item wdt:P131 ?isin . }
}
Humans on twitter without a date of birth
select ?item ?itemLabel ?twitter {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P2002 ?twitter .
filter not exists { ?item wdt:P569 ?dob }
}
Items that are a subclass of building and the associated OSM tag or key
select ?item ?itemLabel ?osm {
?item wdt:P279 wd:Q41176 .
optional { ?item wdt:P1282 ?osm }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Items with a PLU. Including the common name if there is one.
select ?item ?itemLabel ?commonName ?plu {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P4030 ?plu .
optional {
?item wdt:P1843 ?commonName .
filter ( lang(?commonName) = "en" )
}
}
Embassies and diplomatic missions with non-country operator
select distinct ?item ?itemLabel ?operator ?operatorLabel ?country ?countryLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
values ?isa { wd:Q3917681 wd:Q213283 }
?item wdt:P31/wdt:P279* ?isa .
?item wdt:P137 ?operator .
optional { ?item wdt:P17 ?country }
filter (?operator != wd:Q159583)
minus { ?operator wdt:P31 wd:Q6256 }
minus { ?operator wdt:P31 wd:Q3624078 }
minus { ?operator wdt:P31 wd:Q15634554 }
minus { ?operator wdt:P31 wd:Q3024240 }
minus { ?operator wdt:P31 wd:Q4120211 }
minus { ?operator wdt:P31 wd:Q19953632 }
minus { ?operator wdt:P31 wd:Q245065 }
}
Cities connected by the European route E40
#defaultView:Map
SELECT ?city ?cityLabel ?coordinates
WHERE
{
VALUES ?highway {wd:Q327162 }
?highway wdt:P2789 ?city .
?city wdt:P625 ?coordinates .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
airport terminals
select ?item ?itemLabel ?itemDescription ?country ?countryLabel ?partOf ?partOfLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q849706 .
optional { ?item wdt:P17 ?country }
optional { ?item wdt:P361 ?partOf }
}
Wetherspoon pubs
select ?item ?itemLabel ?location ?locationLabel ?named ?namedLabel ?image {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P127 wd:Q6109362 .
optional { ?item wdt:P276 ?location }
optional { ?item wdt:P18 ?image }
optional { ?item wdt:P138 ?named }
}
UK pubs
select ?item ?itemLabel ?location ?locationLabel ?image {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q212198 .
?item wdt:P17 wd:Q145 .
optional { ?item wdt:P131 ?location . }
optional { ?item wdt:P18 ?image . }
}
Wales
SELECT distinct ?item ?itemLabel ?coordinates ?gss WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?instance ps:P31/wdt:P279* wd:Q2630741 .
?item p:P31 ?instance .
#?item wdt:P131/wdt:P131 wd:Q23157 .
optional { ?item wdt:P836 ?gss } .
MINUS { ?instance pq:P582 [] } .
MINUS { ?item wdt:P402 ?osm } .
?item wdt:P625 ?coordinates .
?item wdt:P131 ?adm3 . ?adm3 wdt:P131 ?adm2
}
UK churches with photo but not Commons category
select ?item ?itemLabel ?image {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q16970 .
?item wdt:P18 ?image .
?item wdt:P17 wd:Q145 .
minus { ?item wdt:P373 ?commonscat }
minus { ?article schema:about ?item ;
schema:isPartOf <https://commons.wikimedia.org/> .
}
}
Top jobs for aristocrats
select distinct ?job ?jobLabel (count(*) as ?count) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P4638 ?peerage .
?item wdt:P106 ?job .
} GROUP BY ?job ?jobLabel ORDER BY DESC(?count)
MP companies house officer IDs
select distinct ?person ?personLabel ?seatLabel ?partyLabel ?companieshouse where
{
?person p:P39 ?ps . ?ps ps:P39 ?t . ?t wdt:P279 wd:Q16707842 .
filter not exists { ?t wdt:P576 ?te } # no end time for term - ongoing
filter not exists { ?ps pq:P582 ?pe } # no end time for this period - ongoing
?ps pq:P4100 ?party . ?ps pq:P768 ?seat .
?person wdt:P5297 ?id .
wd:P5297 wdt:P1630 ?formatterurl . BIND(IRI(REPLACE(?id, '^(.+)$', ?formatterurl)) AS ?companieshouse).
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?personLabel
all companies house officer IDs
select ?item ?itemLabel ?cho {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P5297 ?cho .
}
coordinates of listed manor houses
select ?item ?itemLabel ?nle ?coords {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q879050 .
?item wdt:P1216 ?nle .
?item wdt:P625 ?coords .
}
stock exchange buildings
select ?item ?itemLabel ?building ?buildingLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?building wdt:P31/wdt:P279* wd:Q41176 .
?building wdt:P466 ?item .
?item wdt:P31 wd:Q11691 .
} limit 100
museums within 2 miles of the Museum of Modern Art, NYC
``` sparql
defaultView:Map
SELECT ?item ?itemLabel ?image ?distanceMiles ?coords WHERE { SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } wd:Q188740 wdt:P625 ?MoMA. SERVICE wikibase:around { ?item wdt:P625 ?coords. bd:serviceParam wikibase:center ?MoMA; wikibase:radius "3.21869"; wikibase:distance ?distance. } FILTER(EXISTS { ?item (wdt:P31/(wdt:P279*)) wd:Q33506. }) OPTIONAL { ?item wdt:P18 ?image. } BIND(CONCAT(STR((ROUND(?distance * "62.1371192"^xsd:decimal)) / 100 ), " miles FROM MoMA") AS ?distanceMiles) } ORDER BY (?distance)
### MPs without companies house officer ID
select distinct ?person ?personLabel ?seatLabel ?partyLabel ?dob where { ?person p:P39 ?ps . ?ps ps:P39 ?t . ?t wdt:P279 wd:Q16707842 . filter not exists { ?t wdt:P576 ?te } # no end time for term - ongoing filter not exists { ?ps pq:P582 ?pe } # no end time for this period - ongoing ?ps pq:P4100 ?party . ?ps pq:P768 ?seat . minus { ?person wdt:P5297 ?id } optional { ?person wdt:P569 ?dob } SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } } order by DESC(strlen(?personLabel)) ```
UK politicians with a companies house officer ID
select ?item ?itemLabel ?dob ?cho {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P106 wd:Q82955 .
?item wdt:P27 wd:Q145 .
?item wdt:P569 ?dob .
?item wdt:P5297 ?cho
FILTER (?dob > "1890-01-01T00:00:00Z"^^xsd:dateTime) .
}
province of the Netherlands
select distinct ?osm ?itemLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
values ?isa {wd:Q134390}
?item wdt:P31 ?isa .
?item wdt:P402 ?osm .
}
UK nobles born after 1960
select distinct ?item ?itemLabel ?dob where {
?item rdfs:label ?itemLabel .
FILTER(LANG(?itemLabel) = "en") .
?item wdt:P27 wd:Q145 .
?item wdt:P569 ?dob .
FILTER (?dob > "1960-01-01T00:00:00Z"^^xsd:dateTime) .
MINUS {?item wdt:P4638 ?peerage}
} limit 100
'The Peerage' duplicate items, same name and year of birth
Too complex, results in a timeout
select ?item1 ?label1 ?item2 ?label2 (year(?dob1) as ?dob) where {
?item1 rdfs:label ?label1 .
?item2 rdfs:label ?label2 .
?item1 wdt:P31 wd:Q5 .
?item2 wdt:P31 wd:Q5 .
?item1 wdt:P569 ?dob1 .
?item2 wdt:P569 ?dob2 .
?item1 wdt:P4638 ?peerage .
filter (?item1 != ?item2)
filter (?label1 = ?label2)
filter (year(?dob1) = year(?dob2))
} limit 100
Church of England churches with a commons link but no image
select distinct ?item ?itemLabel ?acny ?commons {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P5464 ?acny .
?commons schema:about ?item ;
schema:isPartOf <https://commons.wikimedia.org/> .
minus { ?item wdt:P18 ?image }
}
UK people who are linked to the law (bouncers, lawyers, etc)
select distinct ?item ?itemLabel ?dob ?cho where {
?item rdfs:label ?itemLabel .
FILTER(LANG(?itemLabel) = "en") .
?item wdt:P569 ?dob .
?item wdt:P27 wd:Q145 .
?item wdt:P106/wdt:P279* wd:Q57735705 .
optional { ?item wdt:P5297 ?cho }
}
UK private schools
select ?item ?itemLabel ?itemDescription ?loc ?locLabel ?adminLoc ?adminLocLabel ?streetAddress ?chc {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q2418495 .
?item wdt:P17 wd:Q145 .
optional { ?item wdt:P131 ?adminLoc }
optional { ?item wdt:P276 ?loc }
optional { ?item wdt:P6375 ?streetAddress }
optional { ?item wdt:P2622 ?chc }
}
Church of England churches with a commons link but no image
select distinct ?item ?itemLabel ?acny ?loc ?locLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P5464 ?acny .
optional { ?item wdt:P131 ?loc }
}
Food establishment with URL
select ?item ?itemLabel ?country ?countryLabel ?url where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q27038993 .
?item wdt:P856 ?url .
optional {
?item wdt:P17 ?country .
}
}
Country house hotel locations
select ?item ?itemLabel ?coord {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q64995589 .
?item wdt:P625 ?coord .
}
Country house hotel locations
SELECT ?item ?itemLabel WHERE {
?item rdfs:label ?itemLabel.
?item wdt:P31 wd:Q23442 .
FILTER(((LANG(?itemLabel)) = "en") && (STRENDS(LCASE(?itemLabel), " island")))
}
Statues in London
SELECT distinct ?item ?itemLabel ?coords ?image WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
values ?london { wd:Q23306 wd:84 }
?item wdt:P31/wdt:P279* wd:Q179700 .
optional { ?item wdt:P625 ?coords . }
optional { ?item wdt:P18 ?img . }
{
?item wdt:P131* ?london .
} union {
?item wdt:P276/wdt:P131* ?london .
}
}
Statues in London (too slow, hits timeout)
#defaultView:Map
SELECT distinct ?item ?itemLabel ?coords ?image WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
values ?london { wd:Q23306 wd:84 }
?item wdt:P31/wdt:P279* wd:Q179700 .
optional { ?item wdt:P625 ?coords . }
optional { ?item wdt:P18 ?img . }
{
?item p:P131 ?location .
?location ps:P131 ?london .
minus { ?location pq:P582 ?endTime . }
} union {
?item wdt:P276/wdt:P131* ?london .
}
}
OSM tags and keys of Milden Castle
SELECT DISTINCT ?item ?itemLabel ?tag
WHERE
{
wd:Q6850899 wdt:P31/wdt:P279* ?item .
?item p:P1282/ps:P1282 ?tag .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
statues in London
SELECT distinct ?item ?itemLabel ?coords ?image WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
values ?london { wd:Q23306 wd:84 }
?item wdt:P31/wdt:P279* wd:Q179700 .
optional { ?item wdt:P625 ?coords . }
optional { ?item wdt:P18 ?img . }
{
?item p:P131 ?location .
?location ps:P131 ?london .
minus { ?location pq:P582 ?endTime . }
} union {
?item wdt:P276/wdt:P131* ?london .
}
}
diplomatic missions
select ?item ?itemLabel ?isa ?isaLabel ?coords ?country ?countryLabel ?operator ?operatorLabel ?operatorCode {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 ?isa .
?item wdt:P31/wdt:P279* wd:Q213283 .
?item wdt:P625 ?coords .
optional { ?item wdt:P17 ?country . }
?item wdt:P137 ?operator .
?operator wdt:P297 ?operatorCode .
}
People in thepeerage.com and Facebook
select distinct ?item ?itemLabel ?givenNameLabel ?familyNameLabel ?peerage ?dob ?death ?facebook where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
# ?item wdt:P31 wd:Q5 .
?item rdfs:label ?itemLabel .
FILTER(LANG(?itemLabel) = "en") .
?item wdt:P4638 ?peerage .
?item wdt:P2013 ?facebook .
optional { ?item wdt:P735 ?givenName }
optional { ?item wdt:P734 ?familyName }
optional { ?item wdt:P569 ?dob }
optional { ?item wdt:P570 ?death }
}
118810 results in 37542 ms
sparql
SELECT ?item ?itemLabel ?thePeerage ?gender ?dob ?facebook ?twitter WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P4638 ?thePeerage .
?item wdt:P569 ?dob .
optional { ?item wdt:P21 ?gender }
optional { ?item wdt:P2013 ?facebook }
optional { ?item wdt:P2002 ?twitter }
FILTER ( ?dob > "1940-01-01T00:00:00Z"^^xsd:dateTime)
}
Dry lakes (152 results)
select distinct ?item ?itemLabel ?country ?countryLabel where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q14253637 .
optional { ?item wdt:P17 ?country }
}
Telephone boxes
SELECT distinct ?item ?itemLabel WHERE {
?item wdt:P31 wd:Q712868 .
?item rdfs:label ?itemLabel.
filter (contains(?itemLabel, "K6")
}
Search for family name
SELECT distinct ?item ?label
WHERE
{
SERVICE wikibase:mwapi
{
bd:serviceParam wikibase:endpoint "www.wikidata.org";
wikibase:api "Generator";
mwapi:generator "search";
mwapi:gsrsearch "inlabel:Sebag-Montefiore";
mwapi:gsrlimit "max".
?item wikibase:apiOutputItem mwapi:title.
}
?item wdt:P31 wd:Q5 .
?item rdfs:label ?label.
filter (lang(?label) = "en")
FILTER CONTAINS(?label, "Montefiore")
minus {?item wdt:P734 wd:Q106901222.}
}
OSM tags
SELECT ?item ?itemLabel ?tag_or_key WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item rdf:type wikibase:Property .
?item wdt:P1282 ?tag_or_key .
}
Things named after people who are Jewish
SELECT distinct ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P138 ?person .
{ ?person wdt:P140 wd:Q9268 } union { ?person wdt:P172 wd:Q7325 }
filter (?person != wd:Q302 )
filter (?person != wd:Q345 )
filter (?person != wd:Q81018 )
filter (?person != wd:Q128267 )
}
Houses in the UK (maybe with a website)
SELECT ?item ?itemLabel ?itemDescription ?website WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES ?isa { wd:Q3947 wd:Q16884952 wd:Q879050 wd:Q21092604 wd:Q1343246 }
?item wdt:P31 ?isa .
?item wdt:P17 wd:Q145 .
optional { ?item wdt:P856 ?website }
}
UK journalists
SELECT ?item ?itemLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P6005 ?muckrack .
?item wdt:P27 wd:Q145 .
} order by strlen(str(?itemLabel))
SELECT ?item ?itemLabel ?dob ?cho {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P6005 ?muckrack .
?item wdt:P27 wd:Q145 .
optional { ?item wdt:P569 ?dob }
optional { ?item wdt:P5297 ?cho }
} order by ?dob
UK retail chains and name-suggestion-index ID
SELECT ?item ?itemLabel ?nsi ?isa ?isaLabel ?end WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?isa wdt:P279* wd:Q507619 .
?item wdt:P31 ?isa .
?item wdt:P17 wd:Q145 .
optional { ?item wdt:P576 ?end }
optional { ?item wdt:P8253 ?nsi }
} order by ?itemLabel
Things in the UK with a name-suggestion-index ID
SELECT ?item ?itemLabel ?nsi ?isa ?isaLabel ?end WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 ?isa .
?item wdt:P17 wd:Q145 .
optional { ?item wdt:P576 ?end }
?item wdt:P8253 ?nsi .
} order by ?itemLabel
Github and linked in user names
SELECT ?item ?itemLabel ?github ?linkedin WHERE {
?item wdt:P31 wd:Q5 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P2037 ?github .
optional { ?item wdt:P6634 ?linkedin }
}
Universities
SELECT ?item ?itemLabel ?website ?twitter ?fb ?linkedin WHERE {
?item wdt:P31 wd:Q3918 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
optional { ?item wdt:P856 ?website }
optional { ?item wdt:P2002 ?twitter }
optional { ?item wdt:P2013 ?fb }
optional { ?item wdt:P4264 ?linkedin }
}
Friends of people listed in thepeerage.com
SELECT distinct ?item ?itemLabel ?friend ?friendLabel ?modified ?peerage ?dob ?dod WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P4638 ?peerage .
?item wdt:P3342 ?friend.
?item schema:dateModified ?modified .
?item p:P3342 ?statement .
?statement pq:P3831 wd:Q17297777 .
optional { ?item wdt:P569 ?dob }
optional { ?item wdt:P570 ?dod }
}
edu websites
SELECT distinct ?edu ?web WHERE {
?person wdt:P69 ?edu .
?edu wdt:P856 ?web .
}
people linkedin
SELECT ?item ?itemLabel ?linkedin WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P6634 ?linkedin .
}
MPs
SELECT ?item ?itemLabel ?dob WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P39 wd:Q77685926 .
optional { ?item wdt:P569 ?dob }
}
Children's writers who went to school in Scotland
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P106 wd:Q4853732 .
?item wdt:P69 ?school .
?school wdt:P131* wd:Q22 .
}
Places in UTC+07:00
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q486972 .
?item wdt:P421 wdt:Q6940 .
}
Roads in SF
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q34442 .
?item wdt:P131 wd:Q62
}
Things owned by the national trust
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P127 wd:Q333515
}
Continents with country count and banner image
SELECT ?continent ?continentLabel ?continentDescription ?banner (COUNT(?country) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?country wdt:P30 ?continent .
?country wdt:P31 wd:Q6256 .
?continent wdt:P948 ?banner
}
GROUP BY ?continent ?continentLabel ?continentDescription ?banner
ORDER BY ?continentLabel
Airports with a Wikipedia article
SELECT ?item ?itemLabel ?itemAltLabel ?article WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q1248784 .
?article schema:about ?item .
?article schema:isPartOf <https://en.wikipedia.org/> .
}
MPs with birthdays
select distinct ?person ?personLabel ?seatLabel ?partyLabel ?dob ?gender ?genderLabel where
{
?person p:P39 ?ps . ?ps ps:P39 ?t . ?t wdt:P279 wd:Q16707842 .
filter not exists { ?t wdt:P576 ?te } # no end time for term - ongoing
filter not exists { ?ps pq:P582 ?pe } # no end time for this period - ongoing
?ps pq:P4100 ?party . ?ps pq:P768 ?seat .
optional { ?person wdt:P569 ?dob . }
optional { ?person wdt:P21 ?gender . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?personLabel
Schools in the Netherlands
SELECT ?item ?itemLabel ?article WHERE {
VALUES ?isa {wd:Q159334 wd:Q9826 }
?item wdt:P31 ?isa .
?item wdt:P17 wd:Q55 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
optional {
?item ^schema:about ?article .
?article schema:isPartOf <https://en.wikipedia.org/>;
schema:name ?articlename .
}
}
MP schools locations
select distinct ?person ?personLabel ?school ?schoolLabel ?coords where
{
?person p:P39 ?ps . ?ps ps:P39 ?t . ?t wdt:P279 wd:Q16707842 .
?person wdt:P69 ?school .
values ?edu { wd:Q159334 wd:Q9826 }
?school wdt:P31 wd:Q159334 .
?school wdt:P625 ?coords .
filter not exists { ?t wdt:P576 ?te } # no end time for term - ongoing
filter not exists { ?ps pq:P582 ?pe } # no end time for this period - ongoing
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?personLabel
Schools in Europe
SELECT distinct ?item ?itemLabel ?article WHERE {
?country wdt:P30 wd:Q46 .
VALUES ?isa {wd:Q159334 wd:Q9826 }
?item p:P31/ps:P31 ?isa.
?item wdt:P17 ?country .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
optional {
?item ^schema:about ?article .
?article schema:isPartOf <https://en.wikipedia.org/>;
schema:name ?articlename .
}
}
Schools in Hong Kong
SELECT distinct ?item ?itemLabel ?article WHERE {
values ?country { wd:Q8646 } .
# ?item p:P31/ps:P31 ?isa.
?item wdt:P31/wdt:P279* wd:Q3914 .
?item wdt:P17 ?country .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
optional {
?item ^schema:about ?article .
?article schema:isPartOf <https://en.wikipedia.org/>;
schema:name ?articlename .
}
}
Countries with population
SELECT ?item ?itemLabel ?population WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q6256 .
optional { ?item wdt:P1082 ?population }
}
Count of schools per country
SELECT ?country ?countryLabel (count(*) as ?count) WHERE {
?person wdt:P69 ?school .
?school wdt:P17 ?country .
OPTIONAL {
?country rdfs:label ?countryLabel.
FILTER(LANG(?countryLabel) = "en").
}
} group by ?country ?countryLabel
Business people in Who's Who
SELECT ?item ?itemLabel ?dob ?countryLabel WHERE {
?item wdt:P4789 ?WhoWho .
?item wdt:P569 ?dob .
?item wdt:P27 ?country .
?item wdt:P106 wd:Q43845 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by desc(?dob)
Websites of UK businesses
SELECT ?item ?itemLabel ?web WHERE {
?item wdt:P31 wd:Q4830453 .
?item wdt:P856 ?web .
?item wdt:P17 wd:Q145 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
People with a BBC News Topic ID or BBC Thing ID
SELECT ?item ?itemLabel ?itemDescription ?itemAltLabel ?dob ?facebook WHERE {
?item wdt:P31 wd:Q5 .
optional { ?item wdt:P569 ?dob }
{ ?item wdt:P1617 ?bbcThing } UNION { ?item wdt:P6200 ?bbcTopic }
OPTIONAL { ?item wdt:P2013 ?facebook}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Antarctic fjords named after keyboardists
SELECT DISTINCT ?fjord ?fjordLabel ?person ?personLabel (GROUP_CONCAT(DISTINCT ?jobLabel; SEPARATOR = ", ") AS ?musicalProfession) (SAMPLE(?birth) AS ?birth) (SAMPLE(?death) AS ?death) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
?fjord wdt:P31 wd:Q45776;
wdt:P30 wd:Q51;
wdt:P138 ?person.
?person wdt:P31 wd:Q5;
wdt:P106 ?job;
wdt:P569 ?birth;
wdt:P570 ?death.
?job wdt:P279 wd:Q1075651;
rdfs:label ?jobLabel.
FILTER((LANG(?jobLabel)) = "en")
}
GROUP BY ?fjord ?fjordLabel ?person ?personLabel
impact craters named after chorographers
SELECT ?crator ?cratorLabel ?person ?personLabel (sample(?birth) as ?birth) (SAMPLE(?death) as ?death) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
?crator wdt:P31 wd:Q55818 .
?crator wdt:P138 ?person.
?person wdt:P106 wd:Q2490358 .
OPTIONAL { ?person wdt:P569 ?birth }
OPTIONAL { ?person wdt:P570 ?death }
} group by ?crator ?cratorLabel ?person ?personLabel
Glaciers named after characters in Moby-Dick
SELECT ?item ?itemLabel ?character ?characterLabel ?isaLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q35666 .
?item wdt:P138 ?character .
?character wdt:P1441 wd:Q174596 .
?character wdt:P31 ?isa .
}
What are programming languages named after?
SELECT ?item ?itemLabel ?namedAfter ?namedAfterLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q9143 .
?item wdt:P138 ?namedAfter .
}
Subclass of writer
SELECT ?item ?itemLabel WHERE {
?item wdt:P279 wd:Q36180 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Country locator map collection counts
SELECT ?collection ?collectionLabel (COUNT(*) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q3624078 .
optional {
?item p:P242 ?statement .
?statement ps:P242 ?img .
?statement pq:P195 ?collection .
}
} group by ?collection ?collectionLabel
people tagged with "copyright status as a creator (P7763)" born after 1940
SELECT distinct ?item ?itemLabel ?itemAltLabel ?dob WHERE {
?item wdt:P7763 ?x .
?item wdt:P569 ?dob .
FILTER (?dob >= "1940-01-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
All stations with a UK railway code
SELECT ?item ?itemLabel (group_concat(?code) as ?codes) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31/wdt:P279* wd:Q55488 .
?item wdt:P4755 ?code .
minus { ?item wdt:P576 ?end }
minus { ?item wdt:P31 wd:Q4663385 }
} group by ?item ?itemLabel
British people with a twitter account and without a DoB
SELECT ?item (strlen(?itemLabel) as ?len) ?itemLabel ?twitter WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P27 wd:Q145 .
?item wdt:P2002 ?twitter .
minus { ?item wdt:P569 ?dob . }
}
Nobles born after 1930 who aren't dead
SELECT ?item ?itemLabel ?itemDescription ?itemAltLabel ?dob ?facebook WHERE {
?item wdt:P31 wd:Q5 .
?item wdt:P4638 ?peerage .
?item wdt:P569 ?dob .
minus { ?item wdt:P570 ?dod }
optional { ?item wdt:P2013 ?facebook}
FILTER (?dob >= "1930-01-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
British businesspeople without a DoB
SELECT ?item (strlen(?itemLabel) as ?len) ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P106 wd:Q43845 .
?item wdt:P27 wd:Q145 .
minus { ?item wdt:P569 [] }
}
Nobles who are on Facebook
select distinct ?item ?itemLabel ?givenNameLabel ?familyNameLabel ?peerage ?dob ?death ?facebook where {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
# ?item wdt:P31 wd:Q5 .
?item rdfs:label ?itemLabel .
FILTER(LANG(?itemLabel) = "en") .
?item wdt:P4638 ?peerage .
?item wdt:P2013 ?facebook .
optional { ?item wdt:P735 ?givenName }
optional { ?item wdt:P734 ?familyName }
optional { ?item wdt:P569 ?dob }
optional { ?item wdt:P570 ?death }
}
Nobles born after 1935
SELECT ?item ?itemLabel ?itemDescription ?itemAltLabel ?thepeerage ?dob ?facebook WHERE {
?item wdt:P31 wd:Q5 .
?item wdt:P4638 ?thepeerage .
?item wdt:P569 ?dob .
OPTIONAL { ?item wdt:P2013 ?facebook}
FILTER (?dob >= "1935-01-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Nobles with an IMDB id
SELECT ?item ?itemLabel ?itemDescription ?itemAltLabel ?imdb ?dob ?facebook WHERE {
?item wdt:P31 wd:Q5 .
?item wdt:P345 ?imdb .
?item wdt:P569 ?dob .
?item wdt:P27 wd:Q145 .
OPTIONAL { ?item wdt:P2013 ?facebook}
FILTER (?dob >= "1960-01-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Nobles, born after 1960, with a muckrack id
SELECT ?item ?itemLabel ?itemDescription ?itemAltLabel ?muckrack ?dob ?facebook WHERE {
?item wdt:P31 wd:Q5 .
?item wdt:P6005 ?muckrack .
?item wdt:P569 ?dob .
OPTIONAL { ?item wdt:P2013 ?facebook}
FILTER (?dob >= "1960-01-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
List of noble occupations with counts
SELECT ?item ?itemLabel (COUNT(*) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?person wdt:P106 ?item .
?person wdt:P4638 ?x .
} group by ?item ?itemLabel
ORDER BY desc(?count)
All people with a Facebook id
SELECT ?item ?itemLabel ?itemDescription ?facebook WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P2013 ?facebook .
}
People in Who's Who with a DoB and no DoD
SELECT ?item ?itemLabel ?itemDescription ?itemAltLabel ?dob ?facebook WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P4789 ?whoswho .
?item wdt:P569 ?dob .
minus { ?item wdt:P570 ?dod }
OPTIONAL { ?item wdt:P2013 ?facebook}
}
People in kindredbritain with a DoB and no DoD
SELECT ?item ?itemLabel ?itemDescription ?itemAltLabel ?dob ?facebook WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P3051 ?kindredbritain .
?item wdt:P569 ?dob .
minus { ?item wdt:P570 ?dod }
OPTIONAL { ?item wdt:P2013 ?facebook}
}
British people born after 1960 with an ISNI
SELECT ?item ?itemLabel ?itemAltLabel ?dob WHERE {
?item wdt:P31 wd:Q5 .
?item wdt:P213 ?x .
?item wdt:P569 ?dob .
?item wdt:P27 wd:Q145 .
FILTER (?dob >= "1960-01-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Democracy Club candidates with a DoB
SELECT ?item ?itemLabel ?itemAltLabel ?dob WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P6465 ?dc .
?item wdt:P569 ?dob .
}
family names with a religion
SELECT ?family ?familyLabel ?religionLabel {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?family wdt:P31 wd:Q101352 .
?family wdt:P140 ?religion .
}
British actors with a DoB
SELECT ?item ?itemLabel ?itemAltLabel ?dob WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P106 wd:Q33999 .
?item wdt:P569 ?dob .
?item wdt:P27 wd:Q145 .
}
OSM tag or key, multiple equals signs
SELECT ?item ?itemLabel ?tag_or_key WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P1282 ?tag_or_key .
FILTER (CONTAINS(?tag_or_key, '=')) .
FILTER (regex(?tag_or_key, '^.*=.*='))
}
railway stations named after literary works with coords, images and more
``` sparql select distinct ?item ?itemLabel ?image ?coordinates ?itemCountry ?itemCountryLabel ?place ?placeLabel ?work ?workLabel where { service wikibase:label { bd:serviceParam wikibase:language "en". } ?item wdt:P31/wdt:P279 wd:Q55488 . ?item wdt:P17 ?itemCountry . ?item p:P138 ?statement . optional { ?item wdt:P625 ?coordinates } optional { ?item wdt:P18 ?image } ?statement ps:P138/wdt:P138 ?work . FILTER NOT EXISTS { ?statement pq:P582 ?endTime } ?work wdt:P31/wdt:P279* wd:Q7725634 . optional { ?item wdt:P931 ?place } }
### railway stations named after literary works, less detail
SELECT DISTINCT ?item ?itemLabel ?itemCountry ?itemCountryLabel ?work ?workLabel WHERE { SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } ?item wdt:P31/wdt:P279 wd:Q55488; wdt:P17 ?itemCountry; p:P138 ?statement. ?statement ps:P138/wdt:P138 ?work. ?work wdt:P31/wdt:P279* wd:Q7725634. } ```
British people listed in thepeerage.com, born after 1930
SELECT ?item ?itemLabel ?itemDescription ?itemAltLabel ?dob ?facebook WHERE {
?item wdt:P31 wd:Q5 .
?item wdt:P4638 ?peerage .
?item wdt:P569 ?dob .
?item wdt:P27 wd:Q145 .
OPTIONAL { ?item wdt:P2013 ?facebook}
FILTER (?dob >= "1930-01-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
find father and son relations with an age difference of less than 20 years
SELECT ?child ?childLabel ?childDOB ?father ?fatherLabel ?fatherDOB (year(?childDOB) - year(?fatherDOB) as ?diff) WHERE {
?child wdt:P31 wd:Q5 .
?child wdt:P4638 ?childPeerageID .
?child wdt:P569 ?childDOB .
?child wdt:P22 ?father .
FILTER (?childDOB >= "1960-01-01T00:00:00Z"^^xsd:dateTime)
?father wdt:P31 wd:Q5 .
?father wdt:P4638 ?fatherID .
?father wdt:P569 ?fatherDOB .
filter (year(?childDOB) - year(?fatherDOB) < 20)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
British National Biography (BNB) people with date of birth
SELECT ?item ?itemLabel ?itemAltLabel ?dob WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P5361 ?bnb.
?item wdt:P569 ?dob .
}
Glaciers named after moby dick characters
SELECT ?item ?itemLabel ?character ?characterLabel ?isaLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q35666 .
?item wdt:P138 ?character .
?character wdt:P1441 wd:Q174596 .
?character wdt:P31 ?isa .
}
SELECT ?item ?itemLabel ?character ?characterLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q35666 .
?item wdt:P138 ?character .
?character wdt:P1441 wd:Q174596 .
}
List of sculptors with their DoB
SELECT ?item ?itemLabel ?itemAltLabel ?dob ?precision WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P106 wd:Q1281618 .
?item wdt:P569 ?dob .
?item p:P569/psv:P569 [
wikibase:timePrecision ?precision ;
wikibase:timeValue ?dob ;
] .
FILTER( ?precision >= "10"^^xsd:integer ) # precision of at least month
}
British people with a discog ID and DoB
SELECT ?item ?itemLabel ?itemAltLabel ?dob ?precision WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P1953 ?x .
?item wdt:P569 ?dob .
?item wdt:P27 wd:Q145 .
?item p:P569/psv:P569 [
wikibase:timePrecision ?precision ;
wikibase:timeValue ?dob ;
] .
FILTER( ?precision >= "10"^^xsd:integer ) # precision of at least month
}
Airports named after poets
``` sparql SELECT DISTINCT ?airport ?airportLabel ?airportCountry ?airportCountryLabel ?person ?personLabel (sample(?birth) as ?birth) (SAMPLE(?death) as ?death) WHERE { SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } ?airport (wdt:P31/(wdt:P279*)) wd:Q1248784; wdt:P17 ?airportCountry; p:P138 ?statement. ?statement ps:P138 ?person. ?person wdt:P31 wd:Q5; wdt:P106 wd:Q49757. OPTIONAL { ?person wdt:P569 ?birth } OPTIONAL { ?person wdt:P570 ?death } FILTER(NOT EXISTS { ?statement pq:P582 ?endTime. }) } group by ?airport ?airportLabel ?airportCountry ?airportCountryLabel ?person ?personLabel ?personImage
### Impact craters named after chorographers
SELECT ?crater ?craterLabel ?person ?personLabel (sample(?birth) as ?birth) (SAMPLE(?death) as ?death) WHERE { SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } ?crater wdt:P31 wd:Q5581h8 . ?crater wdt:P138 ?person. ?person wdt:P106 wd:Q2490358 .
OPTIONAL { ?person wdt:P569 ?birth } OPTIONAL { ?person wdt:P570 ?death } } group by ?crater ?craterLabel ?person ?personLabel ```
Cheeses named after towns
#defaultView:ImageGrid
SELECT DISTINCT ?cheese ?cheeseLabel ?town ?townLabel ?image {
?cheese wdt:P31*/wdt:P279* wd:Q10943 ; wdt:P138 ?town .
?town wdt:P31*/wdt:P279* wd:Q486972 .
OPTIONAL { ?cheese wdt:P18 ?image }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en" }
}
ORDER BY ?townLabel
Journalists with a DoB who are listed in thepeerage.com
SELECT ?item ?itemLabel ?dob WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P106 wd:Q1930187 .
?item wdt:P4638 ?peerage .
?item wdt:P569 ?dob .
}
S-Bahn stations in the United Kingdom
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q1793804 .
?item wdt:P17 wd:Q145 .
}
Number of bus stops in each country
SELECT ?item ?itemLabel (COUNT(*) AS ?count) WHERE {
?busstop wdt:P31 wd:Q953806 .
?buststop wdt:P17 ?item .
} group by ?item ?itemLabel
Things named after chorographers
SELECT ?item ?itemLabel (COUNT(*) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?thing wdt:P31 ?item .
?thing wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106 wd:Q2490358 .
} group by ?item ?itemLabel
What type of things are cities named after
SELECT ?isa ?isaLabel (COUNT(*) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q515 .
?item wdt:P138 ?work .
?work wdt:P31 ?isa .
} group by ?isa ?isaLabel
What types of things are named after possibly fictional people
SELECT ?isa ?isaLabel (COUNT(*) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P138 ?person .
?item wdt:P31 ?isa .
?person wdt:P31 wd:Q21070568 .
} GROUP BY ?isa ?isaLabel
Underwater explosions named after possibly fictional people
SELECT ?item ?itemLabel ?person ?personLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q4367188 .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q21070568 .
}
List of website content writers
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P106 wd:Q7978831 .
}
Bus stops named after children's writers
SELECT ?item ?itemLabel ?country ?countryLabel ?person ?personLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
?item (wdt:P31/(wdt:P279*)) wd:Q953806 .
OPTIONAL { ?item wdt:P17 ?country }
?item wdt:P138 ?person.
?person wdt:P31 wd:Q5.
?person wdt:P106 wd:Q4853732.
}
Bus stations named after lawyers
select distinct ?item ?itemLabel ?person ?personLabel where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q494829 .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106/wdt:P279* wd:Q40348 .
}
Things named after popes
select distinct ?thing ?thingLabel (COUNT(*) AS ?count) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* ?thing .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P39 wd:Q19546 .
} group by ?thing ?thingLabel
Nobles with a DoB, born after 1990 matched with other people with the same name and DoB
SELECT ?item ?itemLabel ?person ?personLabel WHERE {
?item wdt:P31 wd:Q5 .
?item wdt:P4638 ?thepeerage .
?item wdt:P569 ?itemDob .
?person wdt:P31 wd:Q5 .
?person wdt:P569 ?personDob .
?item rdfs:label ?itemLabel .
?person rdfs:label ?personLabel .
FILTER (lang(?itemLabel) = "en")
FILTER (lang(?personLabel) = "en")
FILTER (?itemDob >= "1990-01-01T00:00:00Z"^^xsd:dateTime)
FILTER (?personDob >= "1990-01-01T00:00:00Z"^^xsd:dateTime)
filter ( ?item != ?person && ?itemLabel = ?personLabel && ?itemDob = ?personDob)
} limit 10
Nobles born after 1930 with 'works in a collection'
SELECT distinct ?item ?itemLabel ?itemAltLabel ?dob WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P569 ?dob .
?item wdt:P6379 ?x .
FILTER (?dob >= "1930-01-01T00:00:00Z"^^xsd:dateTime)
minus { ?item wdt:P4638 ?peerage }
}
Things named after fictional people
SELECT (COUNT(*) AS ?count) ?isa ?isaLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P138 ?person .
?item wdt:P31 ?isa .
?person wdt:P31 wd:Q15632617 .
} group by ?isa ?isaLabel
Things named after children's writers
``` sparql select distinct ?isa ?isaLabel (count() as ?count) where { service wikibase:label { bd:serviceParam wikibase:language "en". } ?item wdt:P31 ?isa . ?item wdt:P138 ?person . ?person wdt:P31 wd:Q5 . ?person wdt:P106/wdt:P279 wd:Q4853732 . } GROUP BY ?isa ?isaLabel ORDER BY DESC(?count)
### Asteroids named after cartoonists
SELECT ?asteroid ?asteroidLabel ?discovered ?person ?personLabel ?birth ?death WHERE { SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } ?asteroid (wdt:P31/(wdt:P279*)) wd:Q3863. ?asteroid wdt:P138 ?person. ?person wdt:P31 wd:Q5. ?person wdt:P106 wd:Q1114448. OPTIONAL { ?asteroid wdt:P575 ?discovered } OPTIONAL { ?person wdt:P569 ?birth } OPTIONAL { ?person wdt:P570 ?death } }
SELECT DISTINCT ?asteroid ?asteroidLabel ?discovered ?person ?personLabel ?birth ?death WHERE { SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } ?asteroid (wdt:P31/(wdt:P279*)) wd:Q3863; p:P138 ?statement. ?statement ps:P138 ?person. ?person wdt:P31 wd:Q5; wdt:P106 wd:Q1114448. OPTIONAL { ?asteroid wdt:P575 ?discovered } OPTIONAL { ?person wdt:P569 ?birth } OPTIONAL { ?person wdt:P570 ?death } FILTER(NOT EXISTS { ?statement pq:P582 ?endTime. }) } order by ?asteroidLabel
### Jobs of people that have impact craters named after them
select distinct ?job ?jobLabel (count(*) as ?count) where {
service wikibase:label { bd:serviceParam wikibase:language "en". }
?item wdt:P31/wdt:P279* wd:Q55818 .
?item wdt:P138 ?person .
?person wdt:P31 wd:Q5 .
?person wdt:P106/wdt:P279* ?job .
?job wdt:P31/wdt:P279* wd:Q28640 .
} GROUP BY ?job ?jobLabel ORDER BY DESC(?count)
### Nobles who died after 1890
SELECT ?item ?itemLabel ?itemAltLabel ?itemDescription ?dob ?dod WHERE { SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } ?item wdt:P31 wd:Q5 . ?item wdt:P4638 ?thepeerage . optional { ?item wdt:P569 ?dob } ?item wdt:P570 ?dod . FILTER (?dod >= "1890-01-01T00:00:00Z"^xsd:dateTime) } ```
Nobles born after 1990 with a Wikipedia article
SELECT ?item ?itemLabel ?thepeerage ?dob ?article WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5 .
?item wdt:P4638 ?thepeerage .
?item wdt:P569 ?dob .
?item ^schema:about ?article .
?article schema:isPartOf <https://en.wikipedia.org/>;
schema:name ?articlename .
FILTER (?dob > "1990-01-01T00:00:00Z"^^xsd:dateTime)
}
List of elements
SELECT distinct ?item ?itemLabel ?atomicNumber ?elementSymbol ?mass ?density WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q11344 .
?item wdt:P1086 ?atomicNumber .
?item wdt:P246 ?elementSymbol .
optional { ?item wdt:P2067 ?mass . }
optional { ?item wdt:P2054 ?density . }
}
List of continents with locator maps
SELECT ?continent ?continentLabel ?continentDescription ?img (COUNT(?country) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?country wdt:P30 ?continent .
?country wdt:P31 wd:Q6256 .
optional { ?continent wdt:P242 ?img }
}
GROUP BY ?continent ?continentLabel ?continentDescription ?img
ORDER BY ?continentLabel
Countries in Africa
SELECT ?item ?itemLabel ?img WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q3624078 .
?item wdt:P30 wd:Q15 .
optional { ?continent wdt:P242 ?img }
}
Distance from PDX of international airports in the USA
SELECT ?iata ?itemLabel ?patronage ?dist WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q644371 .
?item wdt:P17 wd:Q30 .
?item wdt:P238 ?iata .
?item wdt:P625 ?coords .
?item wdt:P3872 ?patronage .
FILTER (?patronage > 10000000)
wd:Q1425566 wdt:P625 ?pdxCoords .
BIND(geof:distance(?coords, ?pdxCoords) AS ?dist).
} order by ?dist
Antarctic fjords named after keyboardists with details
SELECT DISTINCT ?fjord ?fjordLabel ?person ?personLabel (GROUP_CONCAT(DISTINCT ?jobLabel; SEPARATOR = ", ") AS ?musicalProfession) (SAMPLE(?birth) AS ?birth) (SAMPLE(?death) AS ?death) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
?fjord wdt:P31 wd:Q45776;
wdt:P30 wd:Q51;
wdt:P138 ?person.
?person wdt:P31 wd:Q5;
wdt:P106 ?job;
wdt:P569 ?birth;
wdt:P570 ?death.
?job wdt:P279 wd:Q1075651;
rdfs:label ?jobLabel.
FILTER((LANG(?jobLabel)) = "en")
}
GROUP BY ?fjord ?fjordLabel ?person ?personLabel
Things in Oregon named after people grouped by job
SELECT ?job ?jobLabel (count(*) as ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P131+ wd:Q824 .
?item wdt:P138+ ?namedAfter .
?namedAfter wdt:P106 ?job
} group by ?job ?jobLabel
Things named after the Columbia River
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P131+ wd:Q824 .
?item wdt:P138 wd:Q2251 .
}
footbridge over railway line
SELECT ?item ?itemLabel ?line ?lineLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q1068842 .
?item wdt:P177 ?line .
?line wdt:P31/wdt:P279* wd:Q728937 .
minus { ?line wdt:P31 wd:Q728937 }
}
OSM tags
SELECT ?item ?itemLabel ?osm WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P1282 ?osm .
}
How many borders does each country have?
SELECT ?item ?itemLabel (COUNT(*) AS ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P47 ?other .
?item wdt:P31 wd:Q3624078 .
} group by ?item ?itemLabel
Beaches in the UK
SELECT ?item ?itemLabel ?coords WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q40080 .
?item wdt:P17 wd:Q145 .
?item wdt:P625 ?coords .
}
Things in Portland, OR with external identifiers
SELECT ?item ?itemLabel ?itemDescription (count(?propertyItem) as ?count) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P131 wd:Q6106 .
?item ?propertyRel ?value .
?propertyItem wikibase:directClaim ?propertyRel .
values ?isa { wd:Q19847637 wd:Q19829908 wd:Q18618628 wd:Q28916621 }
?propertyItem wdt:P31 ?isa .
} group by ?item ?itemLabel ?itemDescription
Wards in the UK
SELECT ?item ?itemLabel ?coords ?in ?inLabel ?gss ?rel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q589282 .
?item wdt:P17 wd:Q145 .
optional { ?item wdt:P625 ?coords }
optional { ?item wdt:P131 ?in }
optional { ?item p:P836/ps:P836 ?gss }
optional { ?item wdt:P402 ?rel }
}
Cities where the airport code and rail station code are the same
36 results ``` sparql SELECT ?code ?place ?placeLabel ?country ?countryLabel ?airport ?airportLabel ?station ?stationLabel WHERE { SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } VALUES ?codeProperty { wdt:P4755 wdt:P4803 }
?place wdt:P17 ?country . ?airport wdt:P238 ?code . ?airport wdt:P131 ?place . ?station ?codeProperty ?stationCode . ?station wdt:P131 ?place .
FILTER(?code = UCASE(?stationCode))
} ```
hotels linked to hotel buildings
SELECT ?building ?buildingLabel ?hotel ?hotelLabel ?prop ?propLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?building ?prop ?hotel .
?building wdt:P31 wd:Q63099748 .
?hotel wdt:P31 wd:Q27686 .
}
rose cultivars named after screenwriters
SELECT ?person ?personLabel ?dob ?dod ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q26817508 .
?item wdt:P138 ?person .
?person wdt:P106 wd:Q28389 .
optional { ?person wdt:P569 ?dob }
optional { ?person wdt:P570 ?dod }
}
Paintings with depicts and a Wikipedia article
SELECT ?item ?image ?article ?articlename (GROUP_CONCAT(?depicts; SEPARATOR = "; ") AS ?depictsConcat) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q3305213 .
?item wdt:P18 ?image .
?item wdt:P180 ?depicts .
?depicts rdfs:label ?depictsLabel FILTER (lang(?depictsLabel) = "en") .
?item ^schema:about ?article .
?article schema:isPartOf <https://en.wikipedia.org/>;
schema:name ?articlename .
} GROUP BY ?item ?image ?article ?articlename
Nobility with optional DOB and Companies House officer ID
SELECT ?item ?itemLabel ?dob ?cho WHERE {
?item rdfs:label ?itemLabel FILTER (lang(?itemLabel) = "en") .
?item wdt:P31 wd:Q5 .
?item wdt:P4638 ?thepeerage .
optional { ?item wdt:P569 ?dob }
optional { ?item wdt:P5297 ?cho }
}
sparql